En este artículo se describen cómo quitar botones de la barra de herramientas Vista preliminar y cómo utilizar la barra de herramientas\foreigndesk2 en una ejecutable.
Esta técnica se aplica a Microsoft Visual FoxPro 8.0 y versiones anteriores. También esta técnica se aplica a Visual FoxPro 9.0 cuando "REPORTBEHAVIOR 80, SET" está habilitado. Con "REPORTBEHAVIOR" establecido en "90" en Visual FoxPro 9.0, este proceso es mucho más fácil cuando utiliza evento controlado el informe.
Más información
Los pasos siguientes describen cómo quitar el botón Imprimir de la barra de herramientas Vista preliminar. El botón Imprimir se utiliza como un ejemplo. Sin embargo, se pueden quitar cualquiera de los botones. Es posible que desee quitar por ejemplo el botón Imprimir si desea usuarios.
1. Pegue el código siguiente en un archivo de programa (.prg) y a continuación, ejecute el programa desde la ventana de comandos:
LOCAL lcResourceFileStem
IF '05.'$VERSION() && Foxtools required in VFP5
SET LIBRARY TO HOME()+'foxtools.fll'
ENDIF
SET SAFETY OFF
lcResourceFileStem = ADDBS(JUSTPATH(SYS(2005)))+JUSTSTEM(SYS(2005))
SET RESOURCE OFF
* Copy the current resource file to NoPrint which is
* used to store changes to the Print Preview toolbar.
COPY FILE (lcResourceFileStem + ".dbf") ;
TO noprint.DBF
COPY FILE (lcResourceFileStem + ".fpt") ;
TO noprint.fpt
* Remove current settings by deleting all records in the table.
USE noprint.DBF EXCLUSIVE
ZAP
USE
CLOSE ALL
* Create a table to use for a simple report and put some data in it.
DELETE FILE PrintTest.DBF
CREATE TABLE PrintTest (NAME C(30), Address C(20), City C(20), State C(2))
INSERT INTO PrintTest VALUES ("Jodie Garber", "1234 Jones St", "Phoenix", "AZ")
INSERT INTO PrintTest VALUES ("Holly Johnson", "675 Smith St", "Chicago", "IL")
INSERT INTO PrintTest VALUES ("Jack Reacher", "968 Duvall Street", "Key West", "FL")
INSERT INTO PrintTest VALUES ("Beau Borken", "1515 Main St", "York", "MT")
* Create a report and preview it.
CREATE REPORT PrintTest FROM PrintTest COLUMN
USE IN PrintTest
SET RESOURCE TO noprint.DBF
REPORT FORM PrintTest PREVIEW NOWAIT
IF '05.'$VERSION() && Turn off Foxtools in VFP5
SET LIBRARY TO
ENDIF
RETURN
2. Haga clic con el botón secundario en la Barra de título de la barra de herramientas Vista preliminar y a continuación, haga clic en Personalizar. Si se acopla la barra de herramientas Vista preliminar, puede hacer clic con el botón secundario entre los botones de la barra de herramientas.
3. En Categorías, haga clic en Vista preliminar, haga clic en el botón Imprimir y arrástrelo a continuación fuera de la barra.
4. Haga clic en el botón Cerrar para cerrar el cuadro de diálogo Personalizar barra de herramientas.
5. Haga clic en el botón Cerrar de la barra de herramientas Vista preliminar para cerrar la barra de herramientas Vista preliminar.
6. Escriba el comando siguiente en la ventana de comandos:
SET RESOURCE OFF
7. Pegue el código siguiente en un archivo de programa (.prg) y a continuación, ejecute el programa desde la ventana de comandos:
Note: Este paso se utiliza para mostrar que el botón Imprimir se ha quitado de la barra de herramientas Vista preliminar. El código se ejecutará en Visual FoxPro 6.0 y posteriormente pero los pasos que se describen anteriormente se pueden utilizar en Visual FoxPro 5.0. Puede probar en Visual FoxPro 5.0 al generar manualmente un proyecto que tiene un programa principal que contiene el SET RESOURCE TO NoPrint y el comando FORM de REPORT.
#DEFINE CRLF CHR(13) + CHR(10)
LOCAL cMain
CLOSE ALL
* Delete any projects with the same name.
DELETE FILE PrintTest.PJ?
SET SAFETY OFF
* Open the table used by the report.
cMain = "USE PrintTest " + CRLF
* Set the resource file to the one that does not have
* a print button on it.
cMain = cMain + "SET RESOURCE TO NoPrint" + CRLF
cMain = cMain + "REPORT FORM PrintTest PREVIEW" + CRLF
* Save the string cMain to main.prg.
STRTOFILE(cMain,"Main.Prg")
* Create a project and add all the files that the project needs.
CREATE PROJECT PrintTest NOWAIT
_VFP.ActiveProject.Files.Add("Main.Prg")
_VFP.ActiveProject.Files.Add("PrintTest.Frx")
* Add the resource file that the print button was removed
* from and include it in the executable. This makes it read only.
* If the resource file is read only, changes made to the
* environment at runtime will not be saved.
_VFP.ActiveProject.Files.Add("NoPrint.Dbf")
_VFP.ActiveProject.Files.Item(3).Exclude = .F.
* Compile the project into an executable.
_VFP.ActiveProject.Build("PrintTest.Exe",3,.T., .T.)
8. Ejecute PrintTest.exe y tenga en cuenta que la barra de herramientas no tiene un botón Imprimir. Puede hacer doble clic en PrintTest.exe en Explorador de Windows para ejecutar el programa o ejecutar el comando siguiente en la ventana de comandos:
RUN /N PrintTest.exe
9. Haga clic en el botón Cerrar de la barra de herramientas Vista preliminar para cerrar la barra de herramientas.
Microsoft explorer 6.0 
